Импульсный свет в фотографии

о накамерных вспышках, студийных моноблоках, генераторах и т.п..
Текущее время: 15 ноя 2018, 10:51




Начать новую тему Ответить на тему  [ Сообщений: 25 ] 
Автор Сообщение
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:04 
Не в сети
коллега

Зарегистрирован: 27 сен 2012, 00:16
Сообщения: 92
В общем - на суд общественности.

Текущий алгоритм работы: автоматический - делаем одну пробную вспышку - синхронизатор запоминает количество импульсов и на следующую вспышку запускает подключенные к нему. При этом текущее количество импульсов запоминается на следующий сеанс работы. По-идее - даже если запускающая вспышка меняет количество импульсов в зависимости от каких-либо условий, мы будем успешно синхронизироваться с пропуском максимум одного пыха).

Выкладывал схему/прошивку на сайте osipoff.ru, собираясь доделать в сжатые сроки. Однако родился ребенок :) И на "рукоделие" времени не осталось.
Тем не менее, текущий вариант был "обкатан" в течении нескольких месяцев. И особых нареканий не вызывал.

Долго провозился с собственно фотоприемником. В конечном итоге остановился на варианте схемы Waldemar Szymanski на основе мышиного фотодатчика.

Текущая схема и выглядит этот ужас на макетке пока что так:

Изображение Изображение
Посмотреть на Яндекс.Фотках

Ручной режим (обучили на какой пых срабатывать - и срабатывает только на этот пых) пока не писал - для отладки более подходящим оказался автоматический режим.

А по результатам эксплуатации решил совсем от него отказаться. Более разумным оказалось решение добавить возможность запомнить количество импульсов во вспышке по умолчанию. В оригинале прошивки по включению питания устанавливался режим синхронизации по первому импульсу. Как результат - мне приходилось делать "контрольный выстрел" для обучения - теряя первый кадр. В более новой версии прошивки есть возможность запомнить количество импульсов. Соответственно по включению питания мы "стартуем" без дополнительного обучения.

Под спойлером исходник для "альфы" прошивки, (возможно кого-то заинтересует на предмет "покопаться" - нажмите на кнопку "Показать".

Скрытый текст или картинка:
Код:
.include "tn22def.inc"
;********************************************************************
;* Hardware definition:ports and pins
;********************************************************************
.equ      ledc   =portb               ;выходы
.equ       mled   =pb3               ; информационный светодиод
.equ      flashled=pb4               ; светодиод оптрона вспышки
.equ      sensors   =pinb               ;входы
.equ      foto   =pb1               ;фотодатчик
.equ      key      =pb2               ;кнопка
.equ      switch   =pb0               ;переключатель
.equ      pbdir   =0b11111000

;********************************************************************
;* register definition
;********************************************************************
.def      ftemp   =r2                  ;регистры для временного хранения при отработке прерывания - копия темп-а
.def      fsreg   =r3                  ;регистры для временного хранения при отработке прерывания - копия статусного
.def      ttemp   =r4   
.def      temp   =r16               ;многофункциональная временная переменная
.def      flast   =r17               ;количество импульсов в последней серии
.def      fcur   =r18               ;количество импульсов в текущей серии
.def      ctr0   =r19               ;счетчик

;*************************f*******************************************
;* Macro section
;********************************************************************
.macro      mled_on                     ;макрос - включение инф. светодиода
         cbi      ledc,mled
.endm

.macro      mled_off                  ;макрос - включение инф. светодиода
         sbi      ledc,mled
.endm

.macro      flashled_on                  ;макрос - включение светодиода оптрона вспышки
         cbi      ledc,flashled
.endm

.macro      flashled_off               ;макрос - включение светодиода оптрона вспышки
         sbi      ledc,flashled
.endm

.macro      start_tmr0                  ;макрос - запуск таймера (цикл - 250мс)
         ldi      temp,0b00000101
         out      tccr0,temp
.endm

.macro      stop_tmr0                  ;макрос - останов и сброс таймера (цикл - 250мс)
         clr      temp
         out      tccr0,temp
         out      tcnt0,temp
.endm

.macro      enable_ei0                  ;макрос - разрешение прерывания от фотодатчика
         ldi      temp,0b01000000
         out      gimsk,temp
.endm

.macro      disable_ei0                  ;макрос - запрет прерывания от фотодатчика
         clr      temp
         out      gimsk,temp
.endm

;********************************************************************

;* Main programm section
;********************************************************************
;* Interrupt-vectors section
;********************************************************************
         .cseg
         .org    0x000
reset:      rjmp    start               
ei0:      rjmp   ei0_isr               ;точка входа прерывания от фотодатчика      
t0of:      rjmp   t0_isr               ;точка входа прерывания по переполнению таймера   

;********************************************************************
;* Main programm: inits section
;********************************************************************
start:      ldi      temp,ramend            ;установка указателя стека
         out    spl,temp            ; -"-
         ldi      temp,pbdir            ;настройка портов ввода-вывода   
         out    ddrb,temp            ; -"-
         ser    temp               ; -"-   
         out      portb,temp            ; -"-
         ldi      flast,1               ;считаем, что в последней серии был 1 пых
         clr      fcur               ; а в текущей - ессно - 0
         ldi      temp,0b00000010         ; настраиваем таймер
         out      timsk,temp            ; -"-
         clr      temp               ; -"-
         out      tcnt0,temp            ; -"-
         ldi      temp,0b00000010         ;и прерывание от фотодатчика - по переходу 1-0 кстати - возможно это просто.
         out    mcucr,temp            ;Выкинув VT5 и использовав прерывания по 0-1 можно упростить схему - надо проверить   
         sei                        ;разрешить все прерывания вообще
         enable_ei0                  ;и от фотодатчика в частности
                                 
                              ; Показалось разумным сделать индикацию количестваимпульсов в последней серии
blinker:   mov      temp,flast            
blink:      mled_on                     ;мигаем короткими импульсами столько раз, сколько импульсов в серии
         rcall   del30ms               ; -"-
         mled_off                  ; -"-
         rcall   del300ms            ; -"-
         dec      temp               ; -"-
         brne   blink               ; -"-
         rcall   del1s               ;разделитель - секундная пауза
         rjmp   blinker               ; -"-

t0_isr:      mov      ttemp,temp            ;Тут обрабатывается переполнение таймера
         mov      flast,fcur            ;Считаем, что наша вспышка должна "отвспыхивать" все свои импульсы за 250 мс, не более
         ldi      fcur,0               ;и уж если мы попали сюда - значит серия закончена - запомним сколько в ней было импульсов
         stop_tmr0                  ;таймер - стоять!
         mov      temp,ttemp
         reti

ei0_isr:   mov      ftemp,temp            ;а тут обрабатываем сигнал с фотодатчика
         in      fsreg,sreg            ;сохраняем модифицируемые регистры общего пользования
         inc      fcur               ;увеличиваем счетчик импульсов текущей серии
         cp      fcur,flast            ;и сравниваем его со значением предидущего измерения
         brlo   pre_exit            ;если сейчас меньше - то идем на выход
flash:      disable_ei0                  ;иначе - генерируем пых. для начала запрещаем подсчет вспышек
         flashled_on                  ;и пыхаем
         rcall   del50mks            ;длина импульса запуска - 50 мкс
         flashled_off               ;-"-
         rcall   del3ms               ;Ожидаем 3 мс - пока вспышка не закончится
         enable_ei0                  ;и разрешаем снова подсчет вспышек
pre_exit:   start_tmr0                  ;безусловный запуск таймера
exit_isr:   out      sreg,fsreg            ;восстанавливаем модифицируемые регистры общего пользования
         mov      temp,ftemp            ;-"-
         reti


;------------------------------------------------------------------------------------------
del50mks:   push   temp               ;банальная отработка задержки - 50 мкс
         ldi      temp,13
w50mks:      dec      temp
         brne   w50mks
         pop      temp
         ret

;------------------------------------------------------------------------------------------
del3ms:      push   temp               ;банальная отработка задержки - 3 мс
         ldi   temp,60
d3ms:      rcall   del50mks
         dec   temp
         brne   d3ms
         pop      temp
         ret

;------------------------------------------------------------------------------------------
del30ms:   push   temp               ;банальная отработка задержки - 30 мс
         ldi   temp,10
d30ms:      rcall   del3ms
         dec   temp      
         brne   d30ms
         pop      temp
         ret

;------------------------------------------------------------------------------------------
del1s:      push   temp               ;банальная отработка задержки - 1с
         ldi      temp,166
d1s:      rcall   del3ms
         dec      temp      
         brne   d1s
         pop      temp
         ret

;------------------------------------------------------------------------------------------
del300ms:   push   temp               ;;банальная отработка задержки - 300 мс
         ldi      temp,55
d300ms:      rcall   del3ms
         dec      temp      
         brne   d300ms
         pop      temp
         ret

      .exit
;********************************************************************************************************
И хекс-код прошивки:
Код:
:020000020000FC
:1000000002C023C01AC00FED0DBF08EF07BB0FEFF2
:1000100008BB11E0222702E009BF002702BF02E06F
:1000200005BF789400E40BBF012FC3982DD0C39A6D
:1000300039D00A95D1F72FD0F7CF402E122F20E0DC
:10004000002703BF02BF042D1895202E3FB623952D
:10005000211740F000270BBFC49809D0C49A0DD0D7
:1000600000E40BBF05E003BF3FBE022D18950F93C0
:100070000DE00A95F1F70F9108950F930CE3F7DF68
:100080000A95E9F70F9108950F930AE0F6DF0A95B4
:10009000E9F70F9108950F9306EAEFDF0A95E9F764
:1000A0000F9108950F9307E3E8DF0A95E9F70F91A1
:0200B0000895B1
:00000001FF

Несколько ответов на возможные вопросы:
Q: Почему использована Atmel Tiny22L - она ведь снята с производства?
А: 1) У меня просто их много валяется. Подозреваю, у кого-то тоже может найтись. 2) Когда я начинал делать синхронизатор, под рукой ничего не оказалось. 3) отлаживать программу проще на кристаллах имеющих хоть какой-то обьем ОЗУ.
Будет порт на Тини13 (Или тини15). И, возможно, по просьбам заинтересовавшихся - на другие контроллеры (если смогу достать). Да, некоторые изменения в схеме будут. Некритические.
Q: Кварца в схеме нет?
А: нет - использован внутренний RCгенератор (1МГц) - его вполне хватает.
Q: Как пользоваться?
А: Собрать/прошить/подключить. Должнен коротко вспыхивать светодиод. "Пыхнуть" один раз. Подключенная вспышка должна сработать. Если запускающая вспышка дает более чем один импульс - то светодиод будет вспыхивать сериями. Несколько вспышек (по количеству импульсов запускающей вспышки)-пауза. И так по циклу.
На все последующие срабатывания запускающей вспышки, схемка должна поджигать ведомую вспышку по последнему импульсу запускающей.
Q:Почему на схеме нарисован оптотиристор, а на плате явно виден оптотранзистор?
А:Изначально планировал использовать оптотиристор - как замену поджигающему тиристору самой вспышки. Как-никак гальваническая развязка. Но отлаживал на вспышке от Полароида. А там проще было использовать оптотранзистор. С другой стороны - "со стороны" микроконтроллера разница между оптотранзистором или оптотиристором несущественна.

Фух. На первый раз - вроде бы все.
Продолжение следует.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:05 
Не в сети
коллега

Зарегистрирован: 27 сен 2012, 00:16
Сообщения: 92
Кажись закончил.

Внес коррективы в схему. Дописал прошивку.

Кратко о возможностях:
Автоматический, самообучающийся светосинхронизатор.
В данной версии способен управлять четырьмя вспышками.
Гальваническая развязка.

Как работает?
Подсчитывает количество импульсов управляющей вспышки. Запоминает.
На последующую вспышку срабатывает на последний импульс из предыдущего замера.
При этом количество импульсов в текущей серии запоминается снова. Это позволяет менять режимы работы управляющей вспышки без необходимости каких-либо переключений в самом синхронизаторе.
при изменении количества импульсов в серии управляющей вспышки, корректное срабатывание обеспечивается автоматически с пропуском одной вспышки.

Кнопка SB1 используется для:
при коротком (менее 0.5 секунды) нажатии - тестового поджига присоединенных к синхронизатору вспышек (при этом подсчет импульсов блокируется);
При длинном (более 0,5 секунды) нажатии - текущее количество импульсов управляющей вспышки запоминается как количество импульсов по умолчанию. По включению питания синхронизатор будет автоматически загружать это значение.

Схема:
Изображение
«mysynch» на Яндекс.Фотках

Прошивка, схема (gif\sprint layout), краткое описание тут: autosynch.rar.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:06 
Не в сети
любопытный

Зарегистрирован: 26 сен 2012, 15:25
Сообщения: 4
Хм... а архивчик то изничтожен :(


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:06 
Не в сети
коллега

Зарегистрирован: 27 сен 2012, 00:16
Сообщения: 92
Это называется "теплый привет от Яндекса". На народ-диске долго не востребованное автоматом убивается.
Сейчас восстановил:
Изображение

Прошивка: http://upload.com.ua/get/900765940/


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:06 
Не в сети
любопытный

Зарегистрирован: 26 сен 2012, 15:25
Сообщения: 4
т.е это уже на несколько вспышек получается?

А что в качестве U1-4 ?

Описание выше, как пользоваться, соответствует этой схеме?

Я так подробно спрашиваю, т.к спаять спаяю, а вот если что, то вряд ли найду :(
А схемки программатора, желательно простенького, нет


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:07 
Не в сети
коллега

Зарегистрирован: 27 сен 2012, 00:16
Сообщения: 92
Отвечаю по порядку:
- Да. Именно эта версия - до четырех присоединенных вспышек.
- U1..4 использовал MOC3052
- описание в посте от 25.11.2008 соответствуют.

С программатором сложнее. У меня давно спаян боль-мень продвинутый.
Однако думаю из простых оптимален будет AVReal...
Ссылки увы - нету. Но, думаю, найти будет несложно.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:07 
Не в сети
любопытный

Зарегистрирован: 26 сен 2012, 15:25
Сообщения: 4
Спасибо за ответы.
Однако ж :( блин... не могу скачать прошивку :(

микросхема такая подойдет http://www.chip-dip.ru/product0/515427106.aspx


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:08 
Не в сети
коллега

Зарегистрирован: 27 сен 2012, 00:16
Сообщения: 92
На всякий случай перепроверил - качается.
Хотя надо будет нойти нормальный хостинг. Не люблю обменники...

Контроллер по ссылке подойдет. Вполне. У самого такой


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:08 
Не в сети
любопытный

Зарегистрирован: 26 сен 2012, 15:25
Сообщения: 4
Ну теперь только дела за программатором :)

боюсь показаться наглецом ;) А платки рис нет? ;)

Каким можно заменить фототранзистор? В наличии есть BPT-BP2314 и BPT-BP2331.
Вместо KSC945 можно наша поставить, КТ315, например. KSC945 нет в Чипе.

Нужен ли транзистор Т3, если будет применятся только 1 выход? Можно ли прямо с ноги 3 подать на оптрон, как в первой схеме?


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:11 
Не в сети
гость

Зарегистрирован: 05 окт 2012, 14:10
Сообщения: 1
Добрый день digitalr.
Понравился Ваш синхронизатор на Tiny13, захотелось попробовать в работе но прошивка с указанного обменника не качается.
Возможно ли скачать нех ещё где нибудь ?

Раньше делал вот этот Optical Slave Flash Trigger http://www.fancon.cz/slave-flash-trigge ... iagram.gif
Изображение
Но прошива на сайте автора не захотела работать в 12f675 , светодиод на кнопку не реагировал да и сам процессор висел в коме.
При записи прошивки в 12f629 команды кнопки стали восприниматься (светодиод начал моргать) но тиристор не управлялся.
http://www.fancon.cz/slave-flash-trigge ... sh-en.html
В 12f675 заработала прошивка версии V2 .
http://www.pbase.com/sinoline/sft_kit
Но алгоритм работы не очень понятен, так как не соответствует описанию на сайте.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:14 
Не в сети
коллега

Зарегистрирован: 27 сен 2012, 00:42
Сообщения: 91
Откуда: Брест, РБ
9922 писал(а):
Но прошива на сайте автора не захотела работать в 12F675 , светодиод на кнопку не реагировал да и сам процессор висел в коме.
При записи прошивки в 12F629 команды кнопки стали восприниматься (светодиод начал моргать) но тиристор не управлялся.
http://www.fancon.cz/slave-flash-trigge ... sh-en.html
В 12f675 заработала прошивка версии V2 .
http://www.pbase.com/sinoline/sft_kit
Но алгоритм работы не очень понятен, так как не соответствует описанию на сайте.

Я собирал два таких синхронизатора на 12F675 и оба отлично работают, считаю их лучшими светосинхронизаторами. Корпус взял от китайской елочной гирлянды, вид платы и рисунок печатной платы:

Изображение Изображение

При отключении питания необходимо выждать минуту, иначе - виснет. Алгоритм работы совпадает с описанным на сайте. Нажатие на кнопку однократно - включение/выключение, удержание - обучение, светодиод горит непрерывно.
Прошивку брал на сайте http://www.fancon.cz/slave-flash-trigge ... sh-en.html и она рабочая http://www.fancon.cz/slave-flash-trigger/bin/fl6318.hex
Прошивал через ICprog с помощью программатора JDM

Синхронизатор в работе, перезалил в лучшем качестве: http://www.youtube.com/watch?v=oec_Jnl7zHI


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:15 
Не в сети
новичок

Зарегистрирован: 27 сен 2012, 01:00
Сообщения: 5
Здравствуйте. Обновите пожалуйста ссылку прошивки. Она как и на сайте Осипова не работает. А вообще если можно просто выложите код законченой прошивки, чтобы можно было скопипастить и скомпилировать самостоятельно. И не зависить от файлообменников.

Это я насчет прошивки которую выложил digitalr.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:16 
Не в сети
эксперт

Зарегистрирован: 25 сен 2012, 22:00
Сообщения: 8639
Здравствуйте, A_ndrej!
Старые архивы по этому синхронизатору я выложил сюда:
http://impulsite.narod.ru/synchro/autos ... osynch.zip - размер 1,6 Мб
Также рекомендую обратиться к Илье Рязанову, он в своем проекте Дракон 500 реализовал одну из схем самообучаемого светосинхронизатора.
Также доступны ссылки на сайте Pavel Janko: http://www.fancon.cz/slave-flash-trigge ... sh-en.html


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:17 
Можно вопрос?
Какое практическое применение может иметь данный "обучаемый" синхронизатор? Т.е. что нельзя снять без применения этой высоконаучной игрушки!


Вернуться к началу
   
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:18 
Не в сети
коллега

Зарегистрирован: 26 сен 2012, 19:48
Сообщения: 283
Откуда: Самара
У многих фотографов особенно начинающих нет запускалки вообще да и вспышки тоже. Я сам например относительно недавно купил вспышку, а чтото типа студийного света хотелось попробовать вот сделал синхронизатор на второй пых и запускал встроенной вспышкой.
У многих есть внешняя вспышка но например неотключаемый предпых.

У меня есть несколько знакомых у них и кеноны и никоны, иногда у меня просили СЭФ-ы для подсветок. Вот мне легче сделать синхронизатор который бы подошел всем чем обьяснять почему у них незаработает.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:18 
Не в сети
эксперт

Зарегистрирован: 25 сен 2012, 22:00
Сообщения: 8639
1. Такой светосинхронизатор по настоящему универсален. Фотостудия, оснащенная такими светосинхронизаторами, сможет принять и обеспечить работу фотографов с любой фототехникой. Немало "стона" на форумах от владельцев фотоаппаратов Sony, которые пришли в студию без адаптера под их нестандартный вспышечный башмак. Встроенные вспышки с неотключаемым предпыхом, кроме того, имеют различное количество импульсов и интервал между ними. Часто многие фотоработы проще и удобнее выполнять цифрокомпактами, которые не имеют башмака под вспышку и не всегда удается синхронизировать обычными светосинхронизаторами. Для Вас это теория, для других практика.
2. Светосинхронизатор с программируемым микропроцессором потенциально интересен еще и тем, что изменив микропрограмму, можно сравнительно просто получить новые функции. Например, такой программируемый светосинхронизатор можно без изменения "железки" применить для дистанционного управления фотоаппаратом, достаточно только добавить вилку ДУ и новую программу.
3. Стоимость изготовления обучаемого светосинхронизатора не существенно выше стоимости обычных светосинхронизаторов.
4. Если бы потребности в обучаемом светосинхронизаторе не существовало, мы не обсуждали бы здесь эту тему. :)


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:18 
Не в сети
коллега

Зарегистрирован: 26 сен 2012, 19:48
Сообщения: 283
Откуда: Самара
Абсолютно согласен, очень удобная штука чтобы навсегда забыть про количествоимпульсов и у меня чувствительность феноменальная получилась.
Кто собирается делать делайте этот http://www.fancon.cz/slave-flash-trigge ... sh-en.html
всё работает без всяких проблем - рекомендую всем.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:22 
Не в сети
новичок

Зарегистрирован: 27 сен 2012, 01:00
Сообщения: 5
Digitalr - Большое спасибо!!!

impulsite писал(а):
Также доступны ссылки на сайте Pavel Janko: http://www.fancon.cz/slave-flash-trigge ... sh-en.html

Спасибо, но пики для меня вообще темный лес. И программатора для него у меня нет.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:23 
Не в сети
коллега

Зарегистрирован: 26 сен 2012, 19:48
Сообщения: 283
Откуда: Самара
программатор нужен простейший.
Лет 10 назад собрал когда учился программировать, так им и пользуюсь.
У меня там схема с логическими элементами.
Покупаете панельку дип8, провод LPT от старого принтера
По стоимости копейки выйдет - дешевле микроконтроллера. Схем полно в интернете. Ничего сложного.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:24 
Не в сети
мастер

Зарегистрирован: 26 сен 2012, 15:27
Сообщения: 1000
Откуда: RU, Crimea, Simferopol
нужен раздел по программаторам.

to admin
сделайте - вылью свои поделки..


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:25 
Не в сети
новичок

Зарегистрирован: 27 сен 2012, 01:00
Сообщения: 5
Да, вот только что посмотрел ссылку на avr прект, которую дал impulsite, а исходника(самого текста) кода там и нет, только hex. И как то страшно его ставить - как кот в мешке. Попробую если получится сам напишу программу на такую же схему, только немного по другому. Контроллер будет запоминать не количество вспышек, а времье от первой вспышки до последней. Таким образом думаю минимизировать задержку на обработку сигнала. Контролер просчитает время когда нужно пыхнуть, еще до нужного момента, а не после того как отпыхает ведущая вспышка.
Но это еще вилами по воде. Рисую пока только блок схему. А получится что то, или нет, не знаю. Если да, то выложу. А если нет то сделаю по HEXу который выложил impulsite. Схема же та же будет:-) Да, конечно исходник проекта на этой странице помог бы разобратся...


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:25 
Не в сети
эксперт

Зарегистрирован: 25 сен 2012, 22:00
Сообщения: 8639
Собираем опыт по программаторам здесь: Программаторы.

A_ndrej, к сожалению это всё, что сохранилось.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:25 
Не в сети
новичок

Зарегистрирован: 27 сен 2012, 01:00
Сообщения: 5
impulsite - и на том спасибо.

digitalr писал(а):
Это называется "теплый привет от Яндекса". На народ-диске долго не востребованное автоматом убивается.
Сейчас восстановил: Изображение

Кстати, если я не ошибаюсь, то у вас перепутаны местами 2 и 3 выводы микроконтролера. Посмотрите на даташит.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:27 
Не в сети
эксперт

Зарегистрирован: 25 сен 2012, 22:00
Сообщения: 8639
A_ndrej, попробуйте связаться с digitalr через его имейл. Он, изготовив образец, не был здесь с июня 2010 года.


Вернуться к началу
  Профиль  
 
Непрочитанное сообщениеДобавлено: 05 окт 2012, 14:27 
Не в сети
новичок

Зарегистрирован: 27 сен 2012, 01:00
Сообщения: 5
Нет, пока не буду - пробую своими силами написать программу. А вот если не получится - попробую связаться.
На ошибку указал (если конечно сам не ошибаюсь), потому что может еще кто-то хочет разобраться.


Вернуться к началу
  Профиль  
 
Показать сообщения за:  Поле сортировки  
Начать новую тему Ответить на тему  [ Сообщений: 25 ] 

Часовой пояс: UTC + 4 часа


Кто сейчас на форуме

Зарегистрированные пользователи: katafei777


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете добавлять вложения

Найти:
Перейти:  

При использовании материалов сайта ПРЯМАЯ ссылка на источник impulsite.ru обязательна!


Создано на основе phpBB® Forum Software © phpBB Group